CE PLUS - Nota 013210
Módulo: CÂMBIO FINANCEIRO
Funcionalidade: SISCOSERV
Data/Hora da Publicação: 21/10/2013 09:48:13
Data/Hora Última Alteração: 21/10/2013 09:48:13
Descrição da Nota: MONITOR DE PROCESSAMENTO SISCOSERV
Sintoma
Desenvolvimento de Programa para controlar o envio de XML's para o site do Siscoserv
Solução
Desenvolvimento de Programa para controlar o envio de XML's para o site do Siscoserv
Versões Tratadas
9.0
Pré-Requisitos
Produto:
Nota
Descrição
Informações Complementares
----------------------------------------------------------------------------------------------------
Nota Número 13210 Data: 30/08/2013 Hora: 13:51:27
----------------------------------------------------------------------------------------------------
----------------------------------------------------------------------------------------------------
Nota Número : 13210
Categoria : Melhoria
Prioridade : Média
Versão PW.CE : 9.0
Pacote : 00005
Agrupamento : 00162
----------------------------------------------------------------------------------------------------
Referência às notas relacionadas:
Número - Ordem - Versão - Pacote - Descrição Breve
12604 - 00001 - 9.0 - 00002 - SISCOSERV
12842 - 00002 - 9.0 - 00003 - SISCOSERV
13001 - 00003 - 9.0 - 00004 - ASSOCIAÇÃO DE CONTRATO NCE COM CÂMBIO PRONTO (NOVO PROG)
13028 - 00004 - 9.0 - 00004 - SISCOSERV - ORIGEM PROCESSOS PW.CE
13149 - 00005 - 9.0 - 00005 - SISCOERV - ASSOCIAÇÃO SISCOSERV
----------------------------------------------------------------------------------------------------
MONITOR DE PROCESSAMENTO SISCOSERV
----------------------------------------------------------------------------------------------------
Palavras Chave:
MONITOR DE PROCESSAMENTO SISCOSERV
----------------------------------------------------------------------------------------------------
Objetos da nota:
FUNC /PWS/ZYCA_LOG_SISCOSERV
REPS /PWS/LZYCAGFO01
REPS /PWS/LZYCAGFTOP
TRAN /PWS/ZYCA013
REPS /PWS/MZYCA013F01
REPS /PWS/MZYCA013I01
REPS /PWS/MZYCA013O01
REPS /PWS/MZYCA013TOP
REPS /PWS/SAPMZYCA013
MENU /PWS/ZYCB
----------------------------------------------------------------------------------------------------
Modificações efetuadas em FUNC /PWS/ZYCA_LOG_SISCOSERV
Efetuar as alterações abaixo na parte de parâmetros importação da função:
1) colocar o parâmetro I_ZYCAT030 como opicional;
2) incluir o parâmetro abaixo:
NOME DO PARÂMETRO ATRIB TIPO TIPO REFERÊNCIA VALOR PROPOSTO OPICIONAL TRANSFER. VALOR
I_NRSEQ_ARQ TYPE /PWS/ZYCAT038-NRSEQ_ARQ ' ' 'X' ' '
CÓDIGO FONTE
FUNCTION /pws/zyca_log_siscoserv.
* >> Início da exclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
DATA: itab_zycat034 TYPE TABLE OF /pws/zycat034,
itab_zycat038 TYPE TABLE OF /pws/zycat038.
* << Fim da exclusão
* >> Início da inclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
DATA: itab_zycat034 TYPE TABLE OF /pws/zycat034.
* << Fim da inclusão
wa_zycat030 = i_zycat030.
v_exibe = i_exibe.
* >> Início da inclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
IF i_nrseq_arq IS INITIAL.
* << Fim da inclusão
SELECT * FROM /pws/zycat034
INTO TABLE itab_zycat034
* >> Início da exclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
WHERE nrseq = wa_zycat030-nrseq. "#EC CI_NOFIRST
* << Fim da exclusão
* >> Início da inclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
WHERE nrseq = wa_zycat030-nrseq. "#EC CI_NOFIRST
* << Fim da inclusão
IF sy-subrc EQ 0.
SELECT * FROM /pws/zycat038
INTO TABLE itab_zycat038
FOR ALL ENTRIES IN itab_zycat034
WHERE nrseq_arq = itab_zycat034-nrseq_arq.
ENDIF.
IF NOT itab_zycat038[] IS INITIAL.
CALL SCREEN 0001 STARTING AT 01 01.
ELSE.
RAISE no_log.
* >> Início da inclusão: FUNCTION /PWS/ZYCA_LOG_SISCOSERV
ENDIF.
ELSE.
SELECT * FROM /pws/zycat038
INTO TABLE itab_zycat038
WHERE nrseq_arq = i_nrseq_arq.
IF sy-subrc EQ 0.
SELECT * FROM /pws/zycat034
INTO TABLE itab_zycat034
FOR ALL ENTRIES IN itab_zycat038
WHERE nrseq_arq = itab_zycat038-nrseq_arq.
ENDIF.
IF NOT itab_zycat038[] IS INITIAL.
PERFORM handle_hotspot_click_log
USING 1
'NRSEQ_ARQ'.
ELSE.
RAISE no_log.
ENDIF.
* << Fim da inclusão
ENDIF.
ENDFUNCTION.
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/LZYCAGFO01
module status_0001 output.
set pf-status '0001'.
endmodule.
module cria_alv output.
data: event_handler_log type ref to lcl_event_handler_log.
data: itab_fieldcatalog type lvc_t_fcat,
itab_excluding type ui_functions,
itab_zycat034 type table of /pws/zycat034,
itab_zycat038_alv type table of ty_zycat038_alv,
* >> Início da exclusão: MODULE CRIA_ALV
itab_zycat038 type table of /pws/zycat038,
* << Fim da exclusão
itab_zycat038_ant type table of ty_zycat038_alv.
data: wa_layout type lvc_s_layo,
itab_sort type lvc_t_sort,
wa_sort type lvc_s_sort,
ctl_alv_log type ref to cl_gui_alv_grid,
ctl_log_proc type ref to cl_gui_custom_container,
v_stable type lvc_s_stbl value 'XX'.
if ctl_log_proc is initial.
select * from /pws/zycat034
into table itab_zycat034
...
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/LZYCAGFTOP
...
it_xml type standard table of /pws/zygll1546,
ret_code type i,
size_it_xml type i,
wa_zycat030 type /pws/zycat030,
v_exibe type c,
v_okcode type sy-ucomm,
it_zycat038_alv type table of ty_zycat038_alv.
data: itab_zycat031_alt type table of /pws/zycat031,
wa_zycat031 type /pws/zycat031,
wa_toolbar type stb_button.
* >> Início da inclusão:
data: itab_zycat038 type table of /pws/zycat038.
* << Fim da inclusão
class lcl_event_handler_log definition.
public section.
methods:
handle_hotspot_click_log
for event hotspot_click of cl_gui_alv_grid
importing e_column_id
es_row_no,
handle_data_changed_log
for event data_changed of cl_gui_alv_grid
importing er_data_changed,
...
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/MZYCA013F01
Criar o programa /PWS/MZYCA013F01 do tipo Include na classe de desenvolvimento /PWS/ZYCA
* >> Início da inclusão:
FORM user_command.
CASE sy-dynnr.
WHEN '0001'.
PERFORM user_command_0001.
WHEN '0003'.
PERFORM user_command_0003.
WHEN '0100'.
PERFORM user_command_0100.
ENDCASE.
ENDFORM.
FORM user_command_0001.
CASE sy-ucomm.
WHEN 'CRET'.
PERFORM seleciona_dados.
ENDCASE.
SET SCREEN 0001.
LEAVE SCREEN.
ENDFORM.
FORM seleciona_dados.
DATA: wa_zycat034 TYPE /pws/zycat034, "#EC NEEDED
wa_zycat038 TYPE /pws/zycat038,
v_bloq.
REFRESH: itab_zycat034, itab_zycat038, itab_zycat038_ant.
SELECT * FROM /pws/zycat038
INTO TABLE itab_zycat038
WHERE processo IN s_proce
AND data IN s_data
AND status IN s_status
AND usuario IN s_user.
IF NOT itab_zycat038[] IS INITIAL.
SELECT * FROM /pws/zycat034
INTO TABLE itab_zycat034
FOR ALL ENTRIES IN itab_zycat038
WHERE nrseq_arq = itab_zycat038-nrseq_arq.
DELETE itab_zycat034 WHERE NOT nrseq IN s_nrseq.
IF itab_zycat034[] IS INITIAL.
MESSAGE i015 WITH text-e01.
CLEAR sy-ucomm.
SET SCREEN '0001'.
LEAVE SCREEN.
ENDIF.
ELSE.
MESSAGE i015 WITH text-e01.
CLEAR sy-ucomm.
SET SCREEN '0001'.
LEAVE SCREEN.
ENDIF.
LOOP AT itab_zycat038 INTO wa_zycat038.
READ TABLE itab_zycat034 INTO wa_zycat034
WITH KEY nrseq_arq = wa_zycat038-nrseq_arq.
IF sy-subrc NE 0.
DELETE itab_zycat038.
ENDIF.
ENDLOOP.
PERFORM verifica_autorizacao CHANGING v_bloq.
CHECK v_bloq IS INITIAL.
IF itab_zycat038[] IS INITIAL.
MESSAGE i015 WITH text-e01.
CLEAR sy-ucomm.
SET SCREEN '0001'.
LEAVE SCREEN.
ELSE.
PERFORM carrega_tc.
itab_zycat038_ant[] = itab_zycat038[].
SET SCREEN '0100'.
LEAVE SCREEN.
ENDIF.
ENDFORM.
FORM user_command_0100.
DATA: v_answer(1) TYPE c.
CASE v_okcode.
WHEN 'BACK'.
PERFORM verifica_alteracoes CHANGING v_answer.
IF v_answer EQ 'J' OR v_answer IS INITIAL.
CLEAR: v_okcode, sy-ucomm.
PERFORM desbloqueia_registro.
SET SCREEN 0001.
LEAVE SCREEN.
ELSE.
CLEAR v_okcode.
ENDIF.
WHEN 'SAVE'.
PERFORM grava_dados.
WHEN 'REENVI'.
PERFORM reenvia_lote.
WHEN 'REFRESH'.
PERFORM atualiza_dados.
WHEN 'SELEC'.
PERFORM drill_down.
WHEN 'MARC'.
PERFORM marc_dmarc USING 'X'.
WHEN 'DMARC'.
PERFORM marc_dmarc USING ' '.
WHEN 'DOWNLOAD'.
LOOP AT itab_zycat038t INTO wa_zycat038t
WHERE mark = 'X'.
ENDLOOP.
IF sy-subrc NE 0.
MESSAGE i015 WITH text-i10.
CLEAR v_okcode.
EXIT.
ENDIF.
CLEAR v_okcode.
CLEAR v_path.
CALL SCREEN 0003 STARTING AT 25 10.
ENDCASE.
ENDFORM.
FORM carrega_tc.
DATA: wa_zycat034 TYPE /pws/zycat034,
wa_zycat038 TYPE /pws/zycat038,
wa_zycat038t TYPE ty_zycat038_t,
v_message_store TYPE flag,
v_num_messages TYPE sy-tabix.
REFRESH itab_zycat038t.
LOOP AT itab_zycat038 INTO wa_zycat038.
CLEAR: wa_zycat034, wa_zycat038t.
READ TABLE itab_zycat034 INTO wa_zycat034
WITH KEY nrseq_arq = wa_zycat038-nrseq_arq.
MOVE: wa_zycat034-nrseq TO wa_zycat038t-nrseq,
wa_zycat038-nrseq_arq TO wa_zycat038t-nrseq_arq,
wa_zycat038-processo TO wa_zycat038t-processo,
wa_zycat038-data TO wa_zycat038t-data,
wa_zycat038-prot_transm TO wa_zycat038t-prot_transm,
wa_zycat038-status TO wa_zycat038t-status,
wa_zycat038-cod_erro TO wa_zycat038t-cod_erro,
wa_zycat038-usuario TO wa_zycat038t-usuario.
IF wa_zycat038-status = 'EP' AND
wa_zycat038-prot_transm IS INITIAL.
CLEAR wa_zycat038t-block.
ELSE.
MOVE 'X' TO wa_zycat038t-block.
ENDIF.
IF wa_zycat038t-block IS INITIAL.
PERFORM verifica_bloqueio USING wa_zycat038t-nrseq
CHANGING wa_zycat038t-block.
IF NOT wa_zycat038t-block IS INITIAL.
IF v_message_store IS INITIAL.
CALL FUNCTION 'MESSAGES_INITIALIZE'.
v_message_store = 'X'.
ENDIF.
CALL FUNCTION 'MESSAGE_STORE'
EXPORTING
arbgb = '/PWS/ZYCBM'
msgty = 'W'
msgv1 = text-w01
msgv2 = wa_zycat038t-nrseq
msgv3 = text-w02
txtnr = 061
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
ENDIF.
ENDIF.
APPEND wa_zycat038t TO itab_zycat038t.
ENDLOOP.
IF NOT v_message_store IS INITIAL.
CLEAR v_message_store.
CALL FUNCTION 'MESSAGES_COUNT'
IMPORTING
count = v_num_messages
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
CHECK v_num_messages > 0.
CALL FUNCTION 'MESSAGES_SHOW'
EXPORTING
object = text-004
show_linno = space
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
ENDIF.
DESCRIBE TABLE itab_zycat038t LINES tc_monitor-lines.
tc_monitor-top_line = tc_monitor-current_line = 1.
ENDFORM.
FORM busca_icone USING p_status
CHANGING p_icone.
DATA: v_icon(30) TYPE c.
CASE p_status.
WHEN ' '.
v_icon = 'ICON_STATUS_ALERT'.
WHEN 'EP'.
v_icon = 'ICON_SUBMIT'.
WHEN 'ES'.
v_icon = 'ICON_STATUS_OVERVIEW'.
WHEN 'PM'.
v_icon = 'ICON_WARNING'.
WHEN 'PS'.
v_icon = 'ICON_STATUS_BEST'.
WHEN 'PR' OR 'FA'.
v_icon = 'ICON_STATUS_CRITICAL'.
WHEN 'EX'.
v_icon = 'ICON_DELETE'.
WHEN 'NR'.
v_icon = 'ICON_INCOMPLETE'.
WHEN '01'.
v_icon = 'ICON_DISCONNECT'.
WHEN '02'.
v_icon = 'ICON_DEFECT'.
WHEN '03'.
v_icon = 'ICON_BIW_SOURCE_SYS_OWN'.
ENDCASE.
CALL FUNCTION 'ICON_CREATE'
EXPORTING
name = v_icon
info = text-003
add_stdinf = 'X'
IMPORTING
result = p_icone
EXCEPTIONS
icon_not_found = 1
outputfield_too_short = 2
OTHERS = 3. "#EC *
IF sy-subrc NE 0.
ENDIF.
ENDFORM.
FORM grava_dados.
DATA: wa_zycat038t TYPE ty_zycat038_t,
wa_zycat038_ant TYPE /pws/zycat038.
LOOP AT itab_zycat038t INTO wa_zycat038t
WHERE block IS initial.
IF NOT wa_zycat038t-prot_transm IS INITIAL.
wa_zycat038t-block = 'X'.
MODIFY itab_zycat038t FROM wa_zycat038t
INDEX sy-tabix.
UPDATE /pws/zycat038 SET prot_transm = wa_zycat038t-prot_transm
WHERE nrseq_arq = wa_zycat038t-nrseq_arq.
MOVE wa_zycat038t-nrseq TO v_identificador.
MOVE wa_zycat038t TO /pws/zycat038.
CASE wa_zycat038t-processo.
WHEN 'IRP' OR 'IRF' OR 'CRP' OR 'CRF'.
v_funcionalidade = '/PWS/SAPMZYCA012'.
WHEN OTHERS.
v_funcionalidade = '/PWS/SAPMZYCA012'.
ENDCASE.
PERFORM carrega_log USING '/PWS/ZYCAT038'
'U'
sy-tcode
v_funcionalidade
v_identificador.
READ TABLE itab_zycat038_ant INTO wa_zycat038_ant
WITH KEY nrseq_arq = wa_zycat038t-nrseq_arq.
wa_zycat038_ant-prot_transm = wa_zycat038t-prot_transm.
MODIFY itab_zycat038_ant FROM wa_zycat038_ant
INDEX sy-tabix.
ENDIF.
ENDLOOP.
CLEAR v_okcode.
ENDFORM.
FORM reenvia_lote.
DATA: wa_zycat038t TYPE ty_zycat038_t,
wa_zycat038_ant TYPE /pws/zycat038,
v_message_store TYPE flag,
v_num_messages TYPE sy-tabix.
LOOP AT itab_zycat038t INTO wa_zycat038t
WHERE mark = 'X'.
IF wa_zycat038t-status = 'EP' AND
wa_zycat038t-prot_transm IS INITIAL AND
wa_zycat038t-block IS INITIAL.
CLEAR: wa_zycat038t-status, wa_zycat038t-mark.
MOVE 'X' TO wa_zycat038t-block.
MODIFY itab_zycat038t FROM wa_zycat038t
INDEX sy-tabix.
UPDATE /pws/zycat038 SET status = ' '
WHERE nrseq_arq = wa_zycat038t-nrseq_arq.
MOVE wa_zycat038t-nrseq TO v_identificador.
MOVE wa_zycat038t TO /pws/zycat038.
CASE wa_zycat038t-processo.
WHEN 'IRP' OR 'IRF' OR 'CRP' OR 'CRF'.
v_funcionalidade = '/PWS/SAPMZYCA012'.
WHEN OTHERS.
v_funcionalidade = '/PWS/SAPMZYCA012'.
ENDCASE.
PERFORM carrega_log USING '/PWS/ZYCAT038'
'U'
sy-tcode
v_funcionalidade
v_identificador.
READ TABLE itab_zycat038_ant INTO wa_zycat038_ant
WITH KEY nrseq_arq = wa_zycat038t-nrseq_arq.
wa_zycat038_ant-status = wa_zycat038t-status.
MODIFY itab_zycat038_ant FROM wa_zycat038_ant
INDEX sy-tabix.
IF v_message_store IS INITIAL.
CALL FUNCTION 'MESSAGES_INITIALIZE'.
v_message_store = 'X'.
ENDIF.
CALL FUNCTION 'MESSAGE_STORE'
EXPORTING
arbgb = '/PWS/ZYCBM'
msgty = 'S'
msgv1 = text-i04
msgv2 = wa_zycat038t-nrseq_arq
msgv3 = text-i05
txtnr = 061
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
ELSE.
IF v_message_store IS INITIAL.
CALL FUNCTION 'MESSAGES_INITIALIZE'.
v_message_store = 'X'.
ENDIF.
CALL FUNCTION 'MESSAGE_STORE'
EXPORTING
arbgb = '/PWS/ZYCBM'
msgty = 'E'
msgv1 = text-i02
msgv2 = wa_zycat038t-nrseq_arq
msgv3 = text-i03
txtnr = 061
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
ENDIF.
ENDLOOP.
IF sy-subrc NE 0.
CLEAR v_okcode.
MESSAGE i015 WITH text-i01.
ENDIF.
IF NOT v_message_store IS INITIAL.
CLEAR v_message_store.
CALL FUNCTION 'MESSAGES_COUNT'
IMPORTING
count = v_num_messages
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
CHECK v_num_messages > 0.
CALL FUNCTION 'MESSAGES_SHOW'
EXPORTING
object = text-004
show_linno = space
EXCEPTIONS
OTHERS = 3.
IF sy-subrc EQ 3.
ENDIF.
ENDIF.
CLEAR v_okcode.
ENDFORM.
FORM atualiza_dados.
DATA: v_answer(1) TYPE c.
PERFORM verifica_alteracoes CHANGING v_answer.
IF v_answer EQ 'J' OR v_answer IS INITIAL.
CLEAR v_okcode.
PERFORM seleciona_dados.
ELSE.
CLEAR v_okcode.
ENDIF.
ENDFORM.
FORM verifica_alteracoes CHANGING p_answer.
DATA: wa_zycat038t TYPE ty_zycat038_t,
wa_zycat038 TYPE /pws/zycat038,
wa_zycat038comp TYPE ty_zycat038_comp,
itab_t038comp TYPE TABLE OF ty_zycat038_comp,
itab_t038comp2 TYPE TABLE OF ty_zycat038_comp.
LOOP AT itab_zycat038t INTO wa_zycat038t.
MOVE-CORRESPONDING wa_zycat038t TO wa_zycat038comp.
APPEND wa_zycat038comp TO itab_t038comp.
ENDLOOP.
LOOP AT itab_zycat038_ant INTO wa_zycat038.
MOVE-CORRESPONDING wa_zycat038 TO wa_zycat038comp.
APPEND wa_zycat038comp TO itab_t038comp2.
ENDLOOP.
IF itab_t038comp[] NE itab_t038comp2[].
CALL FUNCTION 'POPUP_TO_CONFIRM_STEP'
EXPORTING
defaultoption = 'N'
textline1 = text-i07
textline2 = text-i08
titel = text-i06
IMPORTING
answer = p_answer
EXCEPTIONS
OTHERS = 1.
IF sy-subrc NE 0.
ENDIF.
ENDIF.
ENDFORM.
FORM drill_down.
DATA: v_field(30) TYPE c,
v_value(20) TYPE c,
v_nrseq_arq TYPE /pws/zycat038-nrseq_arq,
v_nrseq TYPE /pws/zycat034-nrseq,
v_call VALUE 'X'.
GET CURSOR FIELD v_field VALUE v_value.
IF v_field = '/PWS/ZYCAT034-NRSEQ'.
v_nrseq = v_value.
SHIFT v_nrseq RIGHT DELETING TRAILING space.
WHILE sy-subrc EQ 0.
REPLACE space WITH '0' INTO v_nrseq.
ENDWHILE.
SET PARAMETER ID '/PWS/ZYCAP005' FIELD v_nrseq.
EXPORT v_call TO MEMORY ID 'ASS'.
CALL TRANSACTION '/PWS/ZYCA011_E' AND SKIP FIRST SCREEN.
ELSEIF v_field = '/PWS/ZYCAT038-NRSEQ_ARQ'.
v_nrseq_arq = v_value.
SHIFT v_nrseq_arq RIGHT DELETING TRAILING space.
WHILE sy-subrc EQ 0.
REPLACE space WITH '0' INTO v_nrseq_arq.
ENDWHILE.
CALL FUNCTION '/PWS/ZYCA_LOG_SISCOSERV'
EXPORTING
i_exibe = 'X'
i_nrseq_arq = v_nrseq_arq
EXCEPTIONS
no_log = 1
OTHERS = 2.
IF sy-subrc <> 0.
ELSE.
ENDIF.
ENDIF.
CLEAR v_okcode.
ENDFORM.
FORM marc_dmarc USING value(p_marc).
DATA: wa_zycat038t TYPE ty_zycat038_t.
LOOP AT itab_zycat038t INTO wa_zycat038t.
wa_zycat038t-mark = p_marc.
MODIFY itab_zycat038t FROM wa_zycat038t INDEX sy-tabix.
ENDLOOP.
ENDFORM.
FORM verif_autorizacao_bukrs USING p_bukrs
CHANGING p_autorizacao.
AUTHORITY-CHECK OBJECT 'F_BKPF_BUK' ID 'BUKRS'
DUMMY
ID 'ACTVT' FIELD '01'.
IF sy-subrc NE 0.
AUTHORITY-CHECK OBJECT 'F_BKPF_BUK' ID 'BUKRS' FIELD
p_bukrs
ID 'ACTVT' FIELD '01'.
IF sy-subrc NE 0.
p_autorizacao = 'N'.
ENDIF.
ELSE.
AUTHORITY-CHECK OBJECT 'F_BKPF_BUK' ID 'BUKRS' FIELD
p_bukrs
ID 'ACTVT' FIELD '01'.
IF sy-subrc NE 0.
p_autorizacao = 'N'.
ENDIF.
ENDIF.
ENDFORM.
FORM verifica_autorizacao CHANGING p_bloq.
DATA: itab_t030bukrs TYPE TABLE OF ty_zycat030,
wa_t030bukrs TYPE ty_zycat030,
wa_zycat034 TYPE /pws/zycat034,
wa_zycat038t TYPE ty_zycat038_t,
v_autorizacao TYPE c,
v_message_store TYPE flag,
v_num_messages TYPE sy-tabix.
AUTHORITY-CHECK OBJECT 'S_TCODE' ID 'TCD' FIELD sy-tcode.
IF sy-subrc NE 0.
p_bloq = 'X'.
CLEAR v_okcode.
MESSAGE i015 WITH text-e02.
EXIT.
ENDIF.
SELECT nrseq bukrs
FROM /pws/zycat030
INTO TABLE itab_t030bukrs
FOR ALL ENTRIES IN itab_zycat034
WHERE nrseq = itab_zycat034-nrseq.
LOOP AT itab_zycat038t INTO wa_zycat038t.
v_autorizacao = 'S'.
READ TABLE itab_zycat034 INTO wa_zycat034
WITH KEY nrseq_arq = wa_zycat038t-nrseq_arq.
IF sy-subrc EQ 0.
READ TABLE itab_t030bukrs INTO wa_t030bukrs
WITH KEY nrseq = wa_zycat034-nrseq.
IF sy-subrc EQ 0.
PERFORM verif_autorizacao_bukrs USING wa_t030bukrs-bukrs
CHANGING v_autorizacao.
IF v_autorizacao = 'N'.
IF v_message_store IS INITIAL.
CALL FUNCTION 'MESSAGES_INITIALIZE'.
v_message_store = 'X'.
ENDIF.
CALL FUNCTION 'MESSAGE_STORE'
EXPORTING
arbgb = '/PWS/ZYCBM'
msgty = 'E'
msgv1 = text-i04
msgv2 = wa_zycat038t-nrseq_arq
msgv3 = text-i09
msgv4 = wa_t030bukrs-bukrs
txtnr = 061
EXCEPTIONS
OTHERS = 3.
IF sy-subrc NE 0.
ENDIF.
DELETE itab_zycat038t
WHERE nrseq_arq = wa_zycat038t-nrseq_arq.
DELETE itab_zycat038
WHERE nrseq_arq = wa_zycat038t-nrseq_arq.
ENDIF.
ENDIF.
ENDIF.
ENDLOOP.
IF NOT v_message_store IS INITIAL.
CLEAR v_message_store.
CALL FUNCTION 'MESSAGES_COUNT'
IMPORTING
count = v_num_messages
EXCEPTIONS
OTHERS = 3.
IF sy-subrc NE 0.
ENDIF.
CHECK v_num_messages > 0.
CALL FUNCTION 'MESSAGES_SHOW'
EXPORTING
object = 'Mensagens emitidas durante o processo'(m00)
show_linno = space
EXCEPTIONS
OTHERS = 3.
IF sy-subrc NE 0.
ENDIF.
ENDIF.
ENDFORM.
FORM verifica_bloqueio USING p_nrseq
CHANGING p_block.
CALL FUNCTION 'ENQUEUE_/PWS/EZYCAT030'
EXPORTING
nrseq = p_nrseq
EXCEPTIONS
foreign_lock = 1
system_failure = 2
OTHERS = 3.
IF sy-subrc = 0.
CALL FUNCTION 'ENQUEUE_/PWS/EZYCAT031'
EXPORTING
nrseq = p_nrseq
EXCEPTIONS
foreign_lock = 1
system_failure = 2
OTHERS = 3.
IF sy-subrc <> 0.
p_block = 'X'.
ENDIF.
ELSE.
p_block = 'X'.
ENDIF.
ENDFORM.
FORM desbloqueia_registro.
DATA: wa_zycat038t TYPE ty_zycat038_t.
LOOP AT itab_zycat038t INTO wa_zycat038t.
CALL FUNCTION 'DEQUEUE_/PWS/EZYCAT030'
EXPORTING
nrseq = wa_zycat038t-nrseq.
IF sy-subrc NE 0.
ENDIF.
CALL FUNCTION 'DEQUEUE_/PWS/EZYCAT031'
EXPORTING
nrseq = wa_zycat038t-nrseq.
IF sy-subrc NE 0.
ENDIF.
ENDLOOP.
ENDFORM.
FORM user_command_0003.
CASE v_okcode.
WHEN 'CANC'.
CLEAR v_path.
SET SCREEN 0.
LEAVE SCREEN.
WHEN 'ENTER'.
IF v_path IS INITIAL.
CLEAR v_okcode.
MESSAGE e015 WITH text-e03.
ENDIF.
CLEAR v_okcode.
PERFORM download_xml.
ENDCASE.
ENDFORM.
FORM download_xml.
data: wa_zycat038t type ty_zycat038_t,
wa_zycat038 type /pws/zycat038,
it_xml type standard table of /pws/zygll1546,
wa_xml type /pws/zygll1546,
v_indice type /pws/zycat038-indice_xml,
v_name type string,
v_size type i,
v_size_wa type i,
v_lines type i,
v_null(4) type x,
v_pos type i,
v_split1 type string,
v_split2 type string. "#EC NEEDED
loop at itab_zycat038t into wa_zycat038t
where mark = 'X'.
read table itab_zycat038 into wa_zycat038
with key nrseq_arq = wa_zycat038t-nrseq_arq.
if sy-subrc eq 0.
refresh it_xml.
v_indice = wa_zycat038-indice_xml.
import it_xml to it_xml
from database /pws/zycat035(ca)
id v_indice.
if sy-subrc eq 0.
clear v_size.
describe table it_xml lines v_lines.
loop at it_xml into wa_xml.
if sy-tabix < v_lines.
v_size = v_size + 256.
else. "Desconsidera Espaços em Branco na última linha
clear v_pos.
do.
if wa_xml+v_pos(1) = v_null(1).
exit.
endif.
v_pos = v_pos + 1.
v_size = v_size + 1.
enddo.
endif.
endloop.
concatenate v_path wa_zycat038-processo into v_name.
concatenate v_name wa_zycat038t-nrseq
wa_zycat038-data wa_zycat038-hora
into v_name separated by '_'.
concatenate v_name '.xml' into v_name.
call method cl_gui_frontend_services=>gui_download
exporting
bin_filesize = v_size
filename = v_name
filetype = 'BIN'
changing
data_tab = it_xml
exceptions
others = 1.
endif.
endif.
endloop.
clear v_okcode.
set screen 0.
leave screen.
ENDFORM.
* << Fim da inclusão
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/MZYCA013I01
Criar o programa /PWS/MZYCA013I01 do tipo Include na classe de desenvolvimento /PWS/ZYCA
* >> Início da inclusão:
MODULE user_command INPUT.
PERFORM user_command.
ENDMODULE.
MODULE exit_command INPUT.
CASE sy-dynnr.
WHEN '0100'.
LEAVE PROGRAM.
WHEN '0003'.
SET SCREEN 0.
LEAVE SCREEN.
ENDCASE.
ENDMODULE.
MODULE atualiza_itab INPUT.
MOVE: /pws/zycat034-nrseq TO wa_zycat038t-nrseq,
/pws/zycat038-nrseq_arq TO wa_zycat038t-nrseq_arq,
/pws/zycat038-status TO wa_zycat038t-status,
/pws/zycat038-processo TO wa_zycat038t-processo,
/pws/zycat038-data TO wa_zycat038t-data,
/pws/zycat038-prot_transm TO wa_zycat038t-prot_transm,
/pws/zycat038-cod_erro TO wa_zycat038t-cod_erro,
v_block TO wa_zycat038t-block,
v_mark TO wa_zycat038t-mark.
MODIFY itab_zycat038t FROM wa_zycat038t INDEX tc_monitor-current_line.
IF sy-subrc NE 0.
APPEND wa_zycat038t TO itab_zycat038t.
ENDIF.
ENDMODULE.
module matchcode_vpath input.
call function 'TMP_GUI_BROWSE_FOR_FOLDER'
exporting
window_title = text-t01
initial_folder = 'c:\'
importing
selected_folder = v_path
exceptions
cntl_error = 0.
endmodule.
* << Fim da inclusão
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/MZYCA013O01
Criar o programa /PWS/MZYCA013O01 do tipo Include na classe de desenvolvimento /PWS/ZYCA
* >> Início da inclusão:
MODULE status_0100 OUTPUT.
SET PF-STATUS '0100'.
SET TITLEBAR '0100'.
ENDMODULE.
MODULE atualiza_estrutura OUTPUT.
DATA: itab_zycat030 TYPE TABLE OF /pws/zycat030,
wa_zycat030 TYPE /pws/zycat030,
wa_zycat038t TYPE ty_zycat038_t,
itab_zycat040 TYPE TABLE OF /pws/zycat040,
wa_zycat040 TYPE /pws/zycat040,
v_ddtext TYPE dd07v-ddtext,
v_domvalue TYPE dd07v-domvalue_l.
READ TABLE itab_zycat038t INTO wa_zycat038t
INDEX tc_monitor-current_line.
IF sy-subrc EQ 0.
MOVE: wa_zycat038t-nrseq TO /pws/zycat034-nrseq,
wa_zycat038t-nrseq_arq TO /pws/zycat038-nrseq_arq,
wa_zycat038t-status TO /pws/zycat038-status,
wa_zycat038t-processo TO /pws/zycat038-processo,
wa_zycat038t-usuario TO /pws/zycat038-usuario,
wa_zycat038t-data TO /pws/zycat038-data,
wa_zycat038t-prot_transm TO /pws/zycat038-prot_transm,
wa_zycat038t-cod_erro TO /pws/zycat038-cod_erro,
wa_zycat038t-mark TO v_mark,
wa_zycat038t-processo TO v_domvalue,
wa_zycat038t-block TO v_block.
CALL FUNCTION 'DOMAIN_VALUE_GET'
EXPORTING
i_domname = '/PWS/ZYCAD016'
i_domvalue = v_domvalue
IMPORTING
e_ddtext = v_ddtext
EXCEPTIONS
not_exist = 1
OTHERS = 2.
IF sy-subrc <> 0.
ELSE.
MOVE v_ddtext TO v_processo.
ENDIF.
IF itab_zycat040[] IS INITIAL.
SELECT * FROM /pws/zycat040
INTO TABLE itab_zycat040.
ENDIF.
IF itab_zycat030[] IS INITIAL.
SELECT * FROM /pws/zycat030
INTO TABLE itab_zycat030
FOR ALL ENTRIES IN itab_zycat038t
WHERE nrseq = itab_zycat038t-nrseq.
ENDIF.
IF NOT wa_zycat038t-cod_erro IS INITIAL.
READ TABLE itab_zycat030 INTO wa_zycat030
WITH KEY nrseq = wa_zycat038t-nrseq.
READ TABLE itab_zycat040 INTO wa_zycat040
WITH KEY msg_erro = wa_zycat038t-cod_erro
tp_processo = wa_zycat030-tp_processo.
MOVE wa_zycat040-mensagem TO /pws/zycat040-mensagem.
ENDIF.
PERFORM busca_icone USING wa_zycat038t-status
CHANGING v_status.
ENDIF.
IF wa_zycat038t-block IS INITIAL.
LOOP AT SCREEN.
IF screen-name = '/PWS/ZYCAT038-PROT_TRANSM'.
screen-input = '1'.
MODIFY SCREEN.
ENDIF.
ENDLOOP.
ENDIF.
ENDMODULE.
MODULE set_screen OUTPUT.
DATA: wa_cols TYPE cxtab_column.
LOOP AT tc_monitor-cols INTO wa_cols.
IF wa_cols-screen-name = '/PWS/ZYCAT038-PROCESSO' OR
wa_cols-screen-name = '/PWS/ZYCAT038-STATUS' OR
wa_cols-screen-name = '/PWS/ZYCAT038-COD_ERRO' OR
wa_cols-screen-name = 'V_BLOCK'.
wa_cols-invisible = '1'.
MODIFY tc_monitor-cols FROM wa_cols.
ENDIF.
ENDLOOP.
DESCRIBE TABLE itab_zycat038t LINES tc_monitor-lines.
ENDMODULE.
module status_0003 output.
set pf-status '0003'.
endmodule.
* << Fim da inclusão
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/MZYCA013TOP
Criar o programa /PWS/MZYCA013TOP do tipo Include na classe de desenvolvimento /PWS/ZYCA
* >> Início da inclusão:
program /pws/sapmzyca013 message-id /pws/zycbm.
tables:
/pws/zycat034,
/pws/zycat038,
/pws/zycat040.
types:
begin of ty_zycat030,
nrseq type /pws/zycat030-nrseq,
bukrs type /pws/zycat030-bukrs,
end of ty_zycat030,
begin of ty_zycat038_t,
nrseq type /pws/zycat034-nrseq,
nrseq_arq type /pws/zycat038-nrseq_arq,
processo type /pws/zycat038-processo,
data type /pws/zycat038-data,
status type /pws/zycat038-status,
prot_transm type /pws/zycat038-prot_transm,
cod_erro type /pws/zycat038-cod_erro,
usuario type /pws/zycat038-usuario,
mark(1) type c,
block(1) type c,
end of ty_zycat038_t,
begin of ty_zycat038_comp,
nrseq_arq type /pws/zycat038-nrseq_arq,
status type /pws/zycat038-status,
prot_transm type /pws/zycat038-prot_transm,
end of ty_zycat038_comp.
data: itab_zycat034 type table of /pws/zycat034,
itab_zycat038 type table of /pws/zycat038,
itab_zycat038_ant type table of /pws/zycat038,
itab_zycat038t type table of ty_zycat038_t.
data: v_okcode type sy-ucomm,
label_excluido type icons-text,
v_processo(50) type c,
v_status type icons-text,
v_mark type c,
v_funcionalidade type /pws/zyglt390-programa,
v_identificador type /pws/zyglt390-identificador,
v_block type c,
v_path type rlgrap-filename.
controls :
tc_monitor type tableview using screen '0100'.
selection-screen begin of screen 0001.
select-options: s_nrseq for /pws/zycat034-nrseq,
s_proce for /pws/zycat038-processo,
s_data for /pws/zycat038-data,
s_status for /pws/zycat038-status,
s_user for /pws/zycat038-usuario.
selection-screen end of screen 0001.
at selection-screen output.
case sy-dynnr.
when '0001'.
set pf-status '0001'.
set titlebar '0001'.
if s_data[] is initial.
move: 'I' to s_data-sign,
'EQ' to s_data-option,
sy-datum to s_data-low.
s_data-low = s_data-low - 1.
append s_data.
endif.
endcase.
at selection-screen.
perform user_command.
load-of-program.
call function 'ICON_CREATE'
exporting
name = 'ICON_DELETE'
text = text-002
info = text-001
add_stdinf = ' '
importing
result = label_excluido
exceptions
others = 0.
* << Fim da inclusão
----------------------------------------------------------------------------------------------------
Modificações efetuadas em REPS /PWS/SAPMZYCA013
Criar o programa /PWS/SAPMZYCA013 com as informações abaixo:
TÍTULO : Siscoserv - Monitor de Processamento
CATEGORIA : Poll de Módulo
STATUS : Programa de Cliente Produtivo
CL DESENVOLVIMENTO : /PWS/ZYCA
BLOQUEIO EDITOR : ' '
ARITMÉTICA EM PONTO FIXO: 'X'
CÓDIGO FONTE:
* >> Início da inclusão:
INCLUDE /pws/mzyca013top.
INCLUDE /pws/mzyca013o01.
INCLUDE /pws/mzyca013i01.
INCLUDE /pws/mzyca013f01.
include /pws/zygllog .
* << Fim da inclusão
SIMBOLOS DE TEXTOS CRIADOS PARA O PROGRAMA /PWS/SAPMZYCA013
SÍMBOLO TEXT COMD COMM
001 Excluído 8 8
002 Lote Excluído 13 13
003 Status 6 6
004 Mensagens emitidas durante o processo 37 37
E01 Dados não encontrados para o critério de seleção 48 48
E02 Usuário não tem autorização para a transação 44 44
E03 Digitar Caminho para gravação 29 29
I01 Selecionar uma ou mais lotes para reenvio 41 41
I02 Status atual do XML 19 20
I03 não permite reenvio 19 19
I04 XML 3 3
I05 Reiniciado para envio 21 21
I06 Confirmação 11 11
I07 Existem alterações ainda não gravadas. 38 38
I08 Deseja realmente abandonar as alterações? 41 50
I09 . Usuário não tem permissão para a empresa 42 42
I10 Selecionar um ou mais registros para Download 45 45
T01 Selecione o diretório... 24 24
W01 RAS/RVS 7 7
W02 bloqueada por outro programa. 29 29
TEXTOS DE SELEÇÃO CRIADOS PARA O PROGRAMA /PWS/SAPMZYCA013
NOME TEXTO
S_DATA Data Processamento XML
S_NRSEQ Sequencial RAS/RVS
S_PROCE Processo
S_STATUS Status XML
S_USER Usuário
CRIAR O STATUS-GUI 0001 COM AS INFORMAÇÕES ABAIXO:
INCLUIR BOTÃO ESTÁTICO
CÓDIGO DE FUNÇÃO: EXEC
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Executar Monitor
NOME DE ÍCONE: ICON_EXECUTE_OBJECT
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: Executar
SELEÇÃO DIRETA: ' '
TECLA DE ATALHO: F8
ATIVAR O 3º, 4º E 5º BOTÕES DAS TECLAS DE FUNÇÕES COM AS INFORMAÇÕES ABAIXO:
CÓDIGO DE FUNÇÃO: EXIT
CATEGORIA DE FUNÇÃO: E - Comando exit
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Voltar
NOME DE ÍCONE: ' '
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
CRIAR O STATUS-GUI 0003 COM AS INFORMAÇÕES ABAIXO:
ATIVAR O 5º BOTÃO DAS TECLAS DE FUNÇÕES COM AS INFORMAÇÕES ABAIXO:
CÓDIGO DE FUNÇÃO: EXIT
CATEGORIA DE FUNÇÃO: E - Comando exit
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Voltar
NOME DE ÍCONE: ' '
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
ATRIBUIR AS INFORMAÇÕES ABAIXO À TECLA DE FUNÇÃO F8
CÓDIGO DE FUNÇÃO: ENTER
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Confirmação
NOME DE ÍCONE: ' '
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: Confirma
CRIAR O STATUS-GUI 0100 COM AS INFORMAÇÕES ABAIXO:
INCLUIR BOTÃO ESTÁTICO
CÓDIGO DE FUNÇÃO: REENVI
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Reenvio
NOME DE ÍCONE: ICON_PM_INSERT
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: Reenviar Lote
SELEÇÃO DIRETA: ' '
TECLA DE ATALHO: F9
INCLUIR BOTÃO ESTÁTICO
CÓDIGO DE FUNÇÃO: REFRESH
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Atualizar Informações
NOME DE ÍCONE: ICON_REFRESH
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: Atualizar
SELEÇÃO DIRETA: ' '
TECLA DE ATALHO: F7
INCLUIR BOTÃO ESTÁTICO
CÓDIGO DE FUNÇÃO: DOWNLOAD
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Download
NOME DE ÍCONE: ICON_IMPORT
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: Download XML
SELEÇÃO DIRETA: ' '
TECLA DE ATALHO: F6
ATRIBUIR AS INFORMAÇÕES ABAIXO À TECLA DE FUNÇÃO F2
CÓDIGO DE FUNÇÃO: SELEC
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Selecionar
NOME DE ÍCONE: ICON_SELECT_DETAIL
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
SELEÇÃO DIRETA: 'S'
ATIVAR O 2º BOTÃO DAS TECLAS DE FUNÇÕES COM AS INFORMAÇÕES ABAIXO:
CÓDIGO DE FUNÇÃO: SAVE
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Gravar
NOME DE ÍCONE: ICON_SYSTEM_SAVE
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
ATIVAR O 3º e o 5º BOTÃO DAS TECLAS DE FUNÇÕES COM AS INFORMAÇÕES ABAIXO:
CÓDIGO DE FUNÇÃO: BACK
CATEGORIA DE FUNÇÃO: ' ' - Função de Aplicação
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Voltar
NOME DE ÍCONE: ' '
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
ATIVAR O 4º BOTÃO DAS TECLAS DE FUNÇÕES COM AS INFORMAÇÕES ABAIXO:
CÓDIGO DE FUNÇÃO: EXIT
CATEGORIA DE FUNÇÃO: 'E' - Comand Exit
TEXTOS DE FUNÇÃO ESTÁTICOS
TEXTO DE FUNÇÃO: Encerrar
NOME DE ÍCONE: ' '
TEXTO DE ÍCONE: ' '
TEXTO INFORMATIVO: ' '
CRIAR TITLE GUI 0001 COM O TÍTULO 'Monitor Siscoserv - Tela de Seleção'
CRIAR TITLE GUI 0100 COM O TÍTULO 'Siscoserv - Monitor de Processamento'
----------------------------------------------------------------------------------------------------
Modificações efetuadas em tela /PWS/SAPMZYCA013 0002
Solicitar o download da tela junto a equipe de produtos do pw.CE.
----------------------------------------------------------------------------------------------------
Modificações efetuadas em tela /PWS/SAPMZYCA013 0003
Solicitar o download da tela junto a equipe de produtos do pw.CE.
----------------------------------------------------------------------------------------------------
Modificações efetuadas em tela /PWS/SAPMZYCA013 0100
Solicitar o download da tela junto a equipe de produtos do pw.CE.
----------------------------------------------------------------------------------------------------
Modificações efetuadas em TRAN /PWS/ZYCA013
CÓDIGO DE TRANSAÇÃO CRIADO: /PWS/ZYCA013
ATRIBUTOS DA TRANSAÇÃO
TEXTO BREVE: Monitor Siscoserv
OBJETO DE EXECUÇÃO
(X) - PROGRAMA E TELA (TRANSAÇÃO DE DIÁLOGO)
(_) - PROGRAMA E TELA DE SELEÇÃO (TRANSAÇÃO DE REPORT)
TEXTO DA TRANSAÇÃO: Monitor Siscoserv
PROGRAMA: /PWS/SAPMZYCA013
TELA(SELEÇÃO): 0001
OBJETO DE AUTORIZAÇÃO: ' '
(X) - ATUALIZAÇÃO DA VARIANTE DA TRANSAÇÃO STANDARD PERMITIDA
CLASSIFICAÇÃO
CLASSIFICAÇÃO DE TRANSAÇÃO:
(X) - TRANSAÇÃO PROFESSIONAL USER
(_) - TRANSAÇÃO EASY WEB SERVIÇO: ___________________________
CAPACIDADE GUI:
(X) SAP GUI PARA HTML
(X) SAP GUI PARA JAVA
(X) SAP GUI PARA WINDOWS
----------------------------------------------------------------------------------------------------
Modificações efetuadas em MENU /PWS/ZYCB
NO MENU /PWS/ZYCB, INCLUIR A PASTA 'Monitor de Processamento' NO CAMINHO Financeiro --> SISCOSERV,
LOGO ABAIXO DA PASTA 'Associação de RAS/RVS'.
DENTRO DA PASTA 'Monitor de Processamento' CRIADA, INCLUIR A TRANSAÇÃO /PWS/ZYCA013